Add 'another' package to flake.nix and update overlay

flake.nix

@@ -10,6 +10,7 @@
     system = "x86_64-linux";
     overlay = final: prev: {
       # waterfox = final.callPackage ./pkgs/waterfox/default.nix { };
+      another = final.callPackage ./pkgs/another/default.nix { };
       waterfox-bin = final.callPackage ./pkgs/waterfox-bin/default.nix { };
       xcursor-mizuki = final.callPackage ./pkgs/xcursor-mizuki/default.nix { stdenv = final.stdenv; };
     };
@@ -18,7 +19,7 @@
     overlays.default = overlay;
 
     packages.${system} = {
-      inherit (pkgs) waterfox-bin xcursor-mizuki;
+      inherit (pkgs) another waterfox-bin xcursor-mizuki;
       # default = pkgs.waterfox-bin;
     };
   };

pkgs/another/default.nix

@@ -0,0 +1,44 @@
+{
+  lib,
+  fetchurl,
+  appimageTools,
+  makeDesktopItem,
+}:
+
+let
+  pname = "another";
+  version = "0.3.0";
+
+  src = fetchurl {
+    url = "https://github.com/Zfinix/another/releases/download/v${version}/Another_${version}_amd64.AppImage";
+    hash = "sha256-R9gnSZRnrorg2qzXDRFlsuuQa3YHdA0Y8g40EpEAm7g=";
+  };
+
+  desktopItem = makeDesktopItem {
+    name = pname;
+    desktopName = "Another";
+    comment = "Android mirroring and control app";
+    exec = "another";
+    categories = [
+      "Utility"
+    ];
+    terminal = false;
+  };
+in
+appimageTools.wrapType2 {
+  inherit pname version src;
+
+  extraInstallCommands = ''
+    install -Dm444 ${desktopItem}/share/applications/${pname}.desktop \
+      $out/share/applications/${pname}.desktop
+  '';
+
+  meta = {
+    description = "Desktop app for mirroring and controlling Android devices";
+    homepage = "https://github.com/Zfinix/another";
+    license = lib.licenses.mit;
+    mainProgram = "another";
+    sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
+    platforms = [ "x86_64-linux" ];
+  };
+}